Membuat Toolbar Pribadi Microsoft Excel Dengan VBA

Salimyes - Agar mempermudah pekerjaan, terkadang kita sering membuat Toolbar pribadi, baik dalam Microsoft Excel atau lainnya. Disamping itu, kita menginginkan Toolbar tersebut dapat tercipta secara otomatis saat runtime. Berikut ini adalah contoh sederhana untuk membuat Toolbar Pribadi dalam Microsoft Excel saat runtime:

Oleh: Agussalim

Langkah beserta contohnya, sebagai berikut:

1. Buka lembar baru Ms. Excel 2003.
2. Klik menu Tools, Macro, Visual Basic Editor(VBE) (Alt+F11).
3. Dalam VBE, klik menu Insert, Module
4. Ketik(paste) kode berikut kedalam module tersebut(Module1)

Sub InstalToolbar()
On Error GoTo bo1
  HapusToolbar "Salimyes"
  BuatToolbar "Salimyes"
  BuatTombol "Salimyes", "Hari Ini", _
    "Macro1", False, "Tanggal Hari Ini"

  BuatTombol "Salimyes", "Minggu Lalu", _
    "Macro2", True, "Tanggal Minggu Lalu"

bo1:
  Exit Sub
End Sub

Sub BuatToolbar(Nama As String)
On Error GoTo bo1
  Dim myBar As CommandBar
  Set myBar = CommandBars _
    .Add(Name:=Nama, Position:=msoBarTop, _
      Temporary:=True)
  myBar.Visible = True
keluar:
  Exit Sub
bo1:
  If Err.Number <> 5 Then
    MsgBox Err.Description
    Resume keluar
  Else
    Resume keluar
  End If
End Sub

Sub BuatTombol(NamaToolbar As String, _
NamaTombol As String, NamaMacro As String, _
GarisBelakang As Boolean, _
Tips As String)
On Error GoTo bo1
  Dim newTombol
  Set newTombol = CommandBars(NamaToolbar).Controls. _
    Add(Type:=msoControlButton)
  With newTombol
    .BeginGroup = GarisBelakang
    .Caption = NamaTombol
    .OnAction = NamaMacro
    .Style = msoButtonCaption
    .TooltipText = Tips
  End With
bo1:
  Exit Sub
End Sub

Sub HapusToolbar(Nama As String)
  Dim Toolbar As CommandBar
  For Each Toolbar In Application.CommandBars
    If Not Toolbar.BuiltIn And Toolbar.Name = Nama Then
      Toolbar.Delete
      Exit For
    End If
  Next
End Sub

Sub Macro1()
  MsgBox "Hari ini tanggal " & Day(Date), _
    vbInformation, "Tanggal"
End Sub

Sub Macro2()
  MsgBox "Tujuh hari yang lalu tanggal " & _
    Day(Date - 7), vbInformation, "Tanggal"
End Sub

Seperti ini:

5. Ketik(paste) kode berikut dalam Microsoft Excel Objects (ThisWorkbook):

Private Sub Workbook_Open()
  InstalToolbar
End Sub

Seperti ini:

6. Close lembar kerja Microsoft Visual Basic.
7. Simpan Book1 sebagai Add-in Microsoft Excel. Dengan cara: Tekan menu File, SaveAs, beri nama file (toolbar-pribadi.xla). Kemudian atur SaveAs Type menjadi Microsoft Excel Add-in (*.xla). Atur tempat penyimpanan di My Document. Seperti ini:

8. Kemudian tekan Save.
9. Close Micrososft Excel.
10. Buka lagi Micrososft Excel.
11. Pada langkah ini, kita akan membuat kode yang telah kita buat tereksekusi begitu Microsoft Excel dibuka. Caranya:
12. Klik menu Tools, Add-Ins...
13. Klik Browse...
14. Pilih lokasi tempat kita menyimpan Add-in tadi (My Document).
15. Pilih file "toolbar-pribadi.xla"
16. Lalu klik OK
17. Klik OK lagi, dan Restart Micrososft Excel.
18. Nah akan terlihat toolbar pribadi, seperti ini:

19. Selesai. Selamat, Anda telah berhasil belajar membuat Toolbar Pribadi saat Runtime pada Micorosoft Excel Menggunakan VBA. Semoga bermanfaat.

Download, belum bisa. Source Code: toolbar-pribadi.zip »